mirror of
https://github.com/penpot/penpot.git
synced 2026-09-22 20:06:16 +00:00
3cd9bfa9de
* ✨ Auto link tokens when adding external libraries (provisional) * 🔧 Refactor tokens-lib initialization * 🔧 Add separated TokenStatus to store status apart of TokensLib * 🔧 Make all status operations use the new data structure * 🔧 Normalize status helper functions and access token sets by id * 🔧 Rename :tokens-file to :tokens-source * 🎉 Allow the user to choose the tokens-source of a file * 🎉 Make tokens library readonly when it's in an external file * 🎉 Show tokens in library summaries * 🎉 Show source info in sidebar * 🔧 Fix integration tests * 🐛 Propagate changes of token values in external library * 🎉 Layout updates * 🔧 Refactor tokens source calculations * 🔧 Add harder checks for nil or empty values in everything * 🐛 Fix some integration tests * 🔧 Add integration tests for tokens in external libs * 🔧 Validate and repair missing tokens status * 🎉 Make ui changes optional with config flag * 🐛 Propagate tokens after synchronizing components in ext library * 🐛 Propagate tokens after creating new instances * 🐛 Propagate tokens after synchronizing tokens in ext library * 🐛 Add a tokens source icon to libraries section (#11439) * 🐛 Add a tokens source icon to libraries section * 🐛 Fix ellipsis on library names * ♻️ Remove code under flag on legacy component * 🐛 Fix token theme name on inspect tab * 🎉 Add changes notification (#11476) * 🎉 Add changes notification * ♻️ Change fn names * 🐛 Fix tokens source label truncation and missing translations (#11533) * 🐛 Fix tokens source label truncation and missing translations The tokens source file name always showed, even for the current file, and long names wrapped onto a second line instead of truncating because the header used flex-wrap and overflow-wrap: break-word instead of single-line ellipsis. Show the source row unconditionally (it now displays "This file" when the source is the current file, matching the connected-library case), truncate the file name to one line with an ellipsis, and only attach a tooltip with the full name when the text is actually truncated. Replace the hardcoded UI strings with translated ones and add their English and Spanish entries. AI-assisted-by: claude-sonnet-5 * 🐛 Remove redundant effect dependency in tokens source file-name-truncated? was listed as a dependency of the with-effect that checks and observes label truncation, even though it isn't read inside the effect body. Since the effect itself flips that state via check-file-name-truncated, including it as a dependency caused the ResizeObserver to be needlessly disconnected and reconnected on every truncation change. AI-assisted-by: claude-sonnet-5 * 🐛 Fix small visual error * 🐛 Fix problem with plugins * 🐛 Fix playwright tests --------- Co-authored-by: Eva Marco <evamarcod@gmail.com> Co-authored-by: Eva Marco <eva.marco@kaleidos.net> Co-authored-by: alonso.torres <alonso.torres@kaleidos.net>
116 lines
4.2 KiB
Clojure
116 lines
4.2 KiB
Clojure
;; This Source Code Form is subject to the terms of the Mozilla Public
|
|
;; License, v. 2.0. If a copy of the MPL was not distributed with this
|
|
;; file, You can obtain one at http://mozilla.org/MPL/2.0/.
|
|
;;
|
|
;; Copyright (c) KALEIDOS SUBSIDIARY SL
|
|
|
|
(ns frontend-tests.tokens.helpers.state
|
|
(:require
|
|
[app.common.files.tokens :as cfo]
|
|
[app.common.types.tokens-lib :as ctob]
|
|
[app.main.data.changes :as dch]
|
|
[app.main.data.helpers :as dsh]
|
|
[app.main.data.style-dictionary :as sd]
|
|
[app.main.data.workspace.undo :as dwu]
|
|
[beicon.v2.core :as rx]
|
|
[potok.v2.core :as ptk]))
|
|
|
|
(defn end
|
|
"Apply `attributes` that match `token` for `shape-ids`.
|
|
|
|
Optionally remove attributes from `attributes-to-remove`,
|
|
this is useful for applying a single attribute from an attributes set
|
|
while removing other applied tokens from this set."
|
|
[]
|
|
(ptk/reify ::end
|
|
ptk/WatchEvent
|
|
(watch [_ _ _]
|
|
(rx/empty))))
|
|
|
|
(defn end+
|
|
[]
|
|
(ptk/reify ::end+
|
|
ptk/WatchEvent
|
|
(watch [_ state _]
|
|
(let [data (dsh/lookup-file-data state)
|
|
tokens-status (cfo/get-tokens-status data)
|
|
tokens-lib (cfo/get-tokens-lib data)]
|
|
(if (and tokens-status tokens-lib)
|
|
(->> (cfo/get-tokens-in-active-sets tokens-status tokens-lib)
|
|
(sd/resolve-tokens)
|
|
(rx/mapcat #(rx/of (end))))
|
|
(rx/of (end)))))))
|
|
|
|
(defn stop-on
|
|
"Helper function to be used with async version of run-store.
|
|
|
|
Will stop the execution after event with `event-type` has completed."
|
|
[event-type]
|
|
(fn [stream]
|
|
(->> stream
|
|
#_(rx/tap #(prn (ptk/type %)))
|
|
(rx/filter #(ptk/type? event-type %))
|
|
;; Safeguard timeout
|
|
(rx/timeout 200 (rx/of :the/end)))))
|
|
|
|
(def stop-on-send-update-indices
|
|
"Stops on `send-update-indices` function being called, which should be the last function of an event chain."
|
|
(stop-on ::end))
|
|
|
|
(defn watch-undo-stack
|
|
"Maintain the workspace undo stack by watching for commit events.
|
|
Must be emitted before the events under test so undo entries are populated."
|
|
[]
|
|
(ptk/reify ::watch-undo-stack
|
|
ptk/WatchEvent
|
|
(watch [_ _ stream]
|
|
(let [stopper-s (->> stream (rx/filter (ptk/type? ::watch-undo-stack)))]
|
|
(->> stream
|
|
(rx/filter dch/commit?)
|
|
(rx/map deref)
|
|
(rx/filter #(= :local (:source %)))
|
|
(rx/mapcat
|
|
(fn [{:keys [save-undo? undo-changes redo-changes undo-group tags stack-undo? selected-before]}]
|
|
(if (and save-undo? (seq undo-changes))
|
|
(rx/of (dwu/append-undo
|
|
{:undo-changes undo-changes
|
|
:redo-changes redo-changes
|
|
:undo-group undo-group
|
|
:tags tags
|
|
:selected-before selected-before}
|
|
stack-undo?))
|
|
(rx/empty))))
|
|
(rx/take-until stopper-s))))))
|
|
|
|
;; Support for async events in tests
|
|
;; https://chat.kaleidos.net/penpot-partners/pl/tz1yoes3w3fr9qanxqpuhoz3ch
|
|
(defn run-store
|
|
"Async version of `frontend-tests.helpers.state/run-store`."
|
|
([store done events completed-cb]
|
|
(run-store store done events completed-cb nil))
|
|
([store done events completed-cb stopper]
|
|
(let [stream (ptk/input-stream store)
|
|
stopper-s (if (fn? stopper)
|
|
(stopper stream)
|
|
(rx/filter #(= :the/end %) stream))]
|
|
(->> stream
|
|
(rx/take-until stopper-s)
|
|
(rx/last)
|
|
(rx/tap (fn [_]
|
|
(completed-cb @store)))
|
|
(rx/subs! (fn [_] (done))
|
|
(fn [cause]
|
|
(js/console.log "[error]:" cause))
|
|
(fn [_]
|
|
#_(js/console.log "[complete]"))))
|
|
(doseq [event (concat events [(end+)])]
|
|
(ptk/emit! store event))
|
|
(ptk/emit! store :the/end))))
|
|
|
|
(defn run-store-async
|
|
"Helper version of `run-store` that automatically stops on the `send-update-indices` event"
|
|
([store done events completed-cb]
|
|
(run-store store done events completed-cb stop-on-send-update-indices))
|
|
([store done events completed-cb stop-on]
|
|
(run-store store done events completed-cb stop-on)))
|