mirror of
https://github.com/penpot/penpot.git
synced 2026-09-19 18:36:14 +00:00
1f64cc3e52
The summary step reads a filter from .github/scripts, which never landed on this branch, so every run failed with exit code 2 even when all tests passed. Add the filter and tolerate both a missing file and a jq error. Use `!cancelled()` instead of `always()` on the merge job, so it no longer runs after cancel-in-progress killed the shards without uploading their blobs. Lower the JSON report retention to 7 days, the repository maximum. Signed-off-by: David Barragán Merino <david.barragan@kaleidos.net>
42 lines
1.6 KiB
Plaintext
42 lines
1.6 KiB
Plaintext
def specs: [.. | objects | select(has("tests") and has("file"))];
|
|
def dur: [.tests[].results[]?.duration // 0] | add;
|
|
|
|
specs as $s
|
|
| ($s | map(select(any(.tests[]; .status == "unexpected")))) as $failed
|
|
| ($s | map(select(any(.tests[]; .status == "flaky")))) as $flaky
|
|
| ($s | map(select(any(.tests[]; .status == "skipped")))) as $skipped
|
|
| ($s | length) as $total
|
|
| ($s | map(dur) | add // 0 | . / 1000 | floor) as $cpu
|
|
| (if ($failed | length) > 0 then "❌"
|
|
elif ($flaky | length) > 0 then "⚠️"
|
|
else "✅" end) as $icon
|
|
|
|
| "## \($icon) Integration tests\n\n"
|
|
+ "| Total | Passed | Flaky | Failed | Skipped | Test time |\n"
|
|
+ "|---|---|---|---|---|---|\n"
|
|
+ "| \($total) | \($total - ($failed|length) - ($flaky|length) - ($skipped|length)) "
|
|
+ "| \($flaky|length) | \($failed|length) | \($skipped|length) | \($cpu / 60 | floor)m |\n"
|
|
|
|
+ (if ($failed | length) > 0 then
|
|
"\n### Failed\n\n"
|
|
+ ($failed | map("- `\(.file):\(.line)` — \(.title)") | join("\n")) + "\n"
|
|
else "" end)
|
|
|
|
+ (if ($flaky | length) > 0 then
|
|
"\n### Flaky (passed on retry)\n\n"
|
|
+ ($flaky
|
|
| map({ t: "`\(.file):\(.line)` — \(.title)",
|
|
r: ([.tests[].results[]? | select(.status == "failed")] | length) })
|
|
| sort_by(-.r)
|
|
| map("- \(.t) _(\(.r) \(if .r == 1 then "retry" else "retries" end))_")
|
|
| join("\n")) + "\n"
|
|
else "" end)
|
|
|
|
+ (if $total > 0 then
|
|
"\n<details><summary>Slowest specs</summary>\n\n"
|
|
+ ($s | map({ t: "`\(.file)` — \(.title)", d: (dur / 1000 | floor) })
|
|
| sort_by(-.d) | .[0:5]
|
|
| map("- \(.t) — \(.d)s") | join("\n"))
|
|
+ "\n\n</details>\n"
|
|
else "" end)
|